root/fwknop/tags/fwknop-1.9.3/install.pl

#!/usr/bin/perl -w
#
#############################################################################
#
# File: install.pl
#
# URL: http://www.cipherdyne.org/fwknop
#
# Purpose: Installer for fwknop
#
# Credits:  (see the CREDITS file)
#
# Copyright (C) 2004-2007 Michael Rash (mbr@cipherdyne.org)
#
# License (GNU Public License):
#
#    This program is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#    GNU General Public License for more details.
#
#    You should have received a copy of the GNU General Public License
#    along with this program; if not, write to the Free Software
#    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307
#    USA
#
#############################################################################
#
# $Id$
#

use Cwd;
use File::Copy;
use File::Path;
use Getopt::Long;
use Sys::Hostname;
use strict;

#========================== config ===========================
my $USRBIN_DIR  = '/usr/bin';
my $USRSBIN_DIR = '/usr/sbin';

my $fwknop_conf_file = 'fwknop.conf';

### system binaries
my $chkconfigCmd = '/sbin/chkconfig';
my $rcupdateCmd  = '/sbin/rc-update';  ### Gentoo
my $updatercdCmd = '/usr/sbin/update-rc.d';  ### Ubuntu
my $makeCmd      = '/usr/bin/make';
my $perlCmd      = '/usr/bin/perl';
my $gzipCmd      = '/bin/gzip';
my $killallCmd   = '/usr/bin/killall';
my $mknodCmd     = '/bin/mknod';
my $ifconfigCmd  = '/sbin/ifconfig';
my $runlevelCmd  = '/sbin/runlevel';
#======================== end config =========================

### main configuration hash
my %config = ();

my $client_install = 0;
my $bsd_install    = 0;
my $cygwin_install = 0;
my $homedir = '';
my $distro  = '';
my $print_help  = 0;
my $uninstall   = 0;
my $syslog_conf = '';
my $data_method = '';
my $runlevel = -1;
my $init_dir = '/etc/init.d';
my $init_name = 'fwknop';
my $force_mod_re = '';
my $exclude_mod_re = '';
my $force_path_update = 0;
my $sniff_interface   = '';
my $cmdline_force_install = 0;
my $skip_module_install   = 0;
my $force_defaults  = 0;
my $cmdline_os_type = '';
my $os_type = 0;
my $locale = 'C';  ### default LC_ALL env variable
my $no_locale = 0;

### unless --OS-type is used, install.pl will try to figure out the
### OS where fwknop is being installed (this is usually best).
my $OS_LINUX  = 1;
my $OS_BSD    = 2;
my $OS_CYGWIN = 3;
my $OS_DARWIN = 4;  ### Mac OS X

my %os_types = (
    'linux'  => $OS_LINUX,
    'bsd'    => $OS_BSD,
    'cygwin' => $OS_CYGWIN,
    'darwin' => $OS_DARWIN
);

my %exclude_cmds = (
    'mail'        => '',
    'fwknop'      => '',
    'fwknopd'     => '',
    'fwknop_serv' => '',
    'knopmd'      => '',
    'knoptm'      => '',
    'knopwatchd'  => '',
);

### perl module directories
my @required_perl_modules = (
    {   'module'              =>'Class::MethodMaker', ### GnuPG::Interface dependency
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Class-MethodMaker'
    },
    {   'module'              => 'GnuPG::Interface',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'GnuPG-Interface'
    },
    {   'module'              => 'Unix::Syslog',
        'force-install'       => 0,
        'client-mode-install' => 0,
        'mod-dir'             => 'Unix-Syslog'
    },
    {   'module'              => 'Net::IPv4Addr',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Net-IPv4Addr'
    },
    {   'module'              => 'Net::Pcap',
        'force-install'       => 0,
        'client-mode-install' => 0,
        'mod-dir'             => 'Net-Pcap'
    },
    {   'module'              => 'List::MoreUtils',  ### Net::RawIP dependency
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'List-MoreUtils'
    },
    {   'module'              => 'Net::RawIP',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Net-RawIP'
    },
    {   'module'              => 'Net::Ping::External',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Net-Ping-External'
    },
    {   'module'              => 'Digest::SHA',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Digest-SHA'
    },
    {   'module'              => 'Crypt::Rijndael',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Crypt-Rijndael'
    },
    {   'module'              => 'Crypt::CBC',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'Crypt-CBC'
    },
    {   'module'              => 'Term::ReadKey',
        'force-install'       => 0,
        'client-mode-install' => 1,
        'mod-dir'             => 'TermReadKey'
    },
    {   'module'              => 'IPTables::Parse',
        'force-install'       => 1,
        'client-mode-install' => 0,
        'mod-dir'             => 'IPTables-Parse'
    },
    {   'module'              => 'IPTables::ChainMgr',
        'force-install'       => 1,
        'client-mode-install' => 0,
        'mod-dir'             => 'IPTables-ChainMgr'
    }
);

my %cmds = (
    'make'     => $makeCmd,
    'perl'     => $perlCmd,
    'gzip'     => $gzipCmd,
    'killall'  => $killallCmd,
    'mknod'    => $mknodCmd,
    'ifconfig' => $ifconfigCmd,
    'runlevel' => $runlevelCmd
);

my @cmd_search_paths = qw(
    /bin
    /sbin
    /usr/bin
    /usr/sbin
    /usr/local/bin
    /usr/local/sbin
);

### for user answers
my $ACCEPT_YES_DEFAULT = 1;
my $ACCEPT_NO_DEFAULT  = 2;
my $NO_ANS_DEFAULT     = 0;

### make Getopts case sensitive
Getopt::Long::Configure('no_ignore_case');

&usage(1) unless (GetOptions(
    'force-mod-install' => \$cmdline_force_install,  ### force install of all modules
    'Force-mod-regex=s' => \$force_mod_re, ### force specific mod install with regex
    'Exclude-mod-regex=s' => \$exclude_mod_re, ### exclude a particular perl module
    'Skip-mod-install' => \$skip_module_install,
    'OS-type=s'        => \$cmdline_os_type,
    'Cygwin-install'   => \$cygwin_install,
    'BSD-install'   => \$bsd_install,
    'Defaults'      => \$force_defaults,
    'client-only'   => \$client_install, # Force client-only installation
    'path-update'   => \$force_path_update,
    'uninstall'     => \$uninstall,       # Uninstall fwknop.
    'syslog-conf=s' => \$syslog_conf,     # Specify path to syslog config file.
    'interface=s'   => \$sniff_interface, # Specify interface to sniff from
    'init-dir=s'    => \$init_dir,
    'init-name=s'   => \$init_name,
    'runlevel=i'    => \$runlevel,
    'Home-dir=s'    => \$homedir, # specify home directory manually
    'LC_ALL=s'      => \$locale,
    'no-LC_ALL'     => \$no_locale,
    'help'          => \$print_help # Display help.
));
&usage(0) if $print_help;

$force_mod_re = qr|$force_mod_re| if $force_mod_re;
$exclude_mod_re = qr|$exclude_mod_re| if $exclude_mod_re;

### set LC_ALL env variable
$ENV{'LC_ALL'} = $locale unless $no_locale;

&handle_cmd_line();

### import paths from default fwknopd.conf
&import_config();

### check to see if we are installing as a non-root user
&check_non_root_user() unless $client_install;

if ($client_install) {

    ### we are installing as a normal user instead of root, so see
    ### if it is ok to install within the user's home directory
    unless ($homedir) {
        $homedir = $ENV{'HOME'} or die '[*] Could not get home ',
            "directory, use --Home-dir <directory>";
    }

    print
"    The fwknop client will be installed at $homedir/bin/fwknop, and a few\n",
"    perl modules needed by fwknop will be installed in $homedir/lib/fwknop/.\n\n",

    $config{'FWKNOP_MOD_DIR'} = "$homedir/lib/fwknop";
    $USRBIN_DIR = "$homedir/bin";
}

### get the OS type
&get_os() unless $os_type;

if ($os_type == $OS_LINUX) {
    print "[+] OS: Linux\n";
} elsif ($os_type == $OS_CYGWIN) {
    print "[+] OS: Cygwin\n";
} elsif ($os_type == $OS_DARWIN) {
    print "[+] OS: Darwin\n";
} elsif ($os_type == $OS_BSD) {
    print "[+] OS: BSD\n";
}

if ($os_type == $OS_LINUX) {

    $distro = &get_linux_distro();

    if ($distro eq 'redhat' or $distro eq 'fedora') {
        ### add chkconfig only if we are runing on a redhat distro
        $cmds{'chkconfig'} = $chkconfigCmd;
    } elsif ($distro eq 'gentoo') {
        ### add rc-update if we are running on a gentoo distro
        $cmds{'rc-update'} = $rcupdateCmd;
    } elsif ($distro eq 'ubuntu') {
        ### add update-rc.d if we are running on an ubuntu distro
        $cmds{'update-rc.d'} = $updatercdCmd;
    }
    print "[+] Distro: $distro\n";
}

### make sure the system binaries are where we expect
### them to be.
&check_commands();

my $hostname = hostname();

my $src_dir = getcwd() or die "[*] Could not get current working directory.";

if (not $uninstall) {
    &install();
} else {
    &uninstall();
}
exit 0;
#======================= end main ==========================

sub install() {
    print "[+] Installing fwknop on $hostname\n";

    if ($homedir) {
        die "[*] $homedir does not exist" unless -d $homedir;
    }

    my $preserve_rv = 0;
    unless ($client_install) {
        if (&ask_to_stop_fwknop()) {
            &stop_fwknop();
        }

        for my $dir qw| /usr/lib /var/run /var/log /var/lib | {
            unless (-d $dir) {
                mkdir $dir or die "[*] Could not mkdir $dir: $!";
            }
        }
        unless (-d $USRSBIN_DIR) {
            mkdir $USRSBIN_DIR or die "[*] Could not mkdir $USRSBIN_DIR: $!";
        }
        for my $dir qw/FWKNOP_DIR FWKNOP_RUN_DIR
                    FWKNOP_LIB_DIR/ {
            unless (-d $config{$dir}) {
                mkdir $config{$dir}, 0500 or
                    die "[*] Could not mkdir $config{$dir}: $!";
            }
        }
    }
    unless (-d $USRBIN_DIR) {
        print "[+] Creating: $USRBIN_DIR\n";
        mkdir $USRBIN_DIR or die "[*] Could not mkdir $USRBIN_DIR: $!";
    }

    ### config directory
    unless ($client_install) {
        unless (-d $config{'FWKNOP_CONF_DIR'}) {
            ### Note that root will only be able to view files in
            ### /etc/fwknop since fwknop only needs to view fwknop.conf
            ### when being run as a daemon.
            print "[+] Creating config directory: ",
                "$config{'FWKNOP_CONF_DIR'}\n";
            mkdir $config{'FWKNOP_CONF_DIR'}, 0500
                or die "[*] Could not mkdir $config{'FWKNOP_CONF_DIR'}: $!";
        }

        ### archive directory for previously installed config files
        unless (-d "$config{'FWKNOP_CONF_DIR'}/archive") {
            print "[+] Creating config{'FWKNOP_CONF_DIR'}/archive ",
                "directory: $config{'FWKNOP_CONF_DIR'}/archive\n";
            mkdir "$config{'FWKNOP_CONF_DIR'}/archive", 0500 or die
                "[*] Could not mkdir $config{'FWKNOP_CONF_DIR'}/archive: $!";
        }
    }

    print "[+] Several perl modules needed by fwknop will be installed in\n",
        "    $config{'FWKNOP_MOD_DIR'}. Installing them here will keep the ",
        "system perl\n    library tree clean.\n";

    ### make our library directory (for perl modules)
    if ($client_install) {
        unless (-d "$homedir/lib") {
            print "[+] Creating directory $homedir/lib\n";
            mkdir "$homedir/lib", 0755
                or die "[*] Could not mkdir $homedir/lib: $!";
        }
    }
    unless (-d $config{'FWKNOP_MOD_DIR'}) {
        print "[+] Creating directory $config{'FWKNOP_MOD_DIR'}\n";
        mkdir $config{'FWKNOP_MOD_DIR'}, 0755
            or die "[*] Could not mkdir $config{'FWKNOP_MOD_DIR'}: $!";
    }

    ### install perl modules
    unless ($skip_module_install) {
        for my $mod_href (@required_perl_modules) {
            &install_perl_module($mod_href);
        }
    }

    ### special case the NetPacket::<proto> modules since the NetPacket
    ### directory is just for the base class, and we need to make sure
    ### we have each of the NetPacket::IP, NetPacket::ICMP, NetPacket::UDP,
    ### and NetPacket::TCP modules.
    unless ($skip_module_install or $client_install) {
        chdir 'NetPacket' or die "[*] Could not chdir NetPacket directory: $!";
        unless (-e 'Makefile.PL') {
            die "[*] Your NetPacket source directory appears to be incomplete!\n",
                "    Download the latest sources from ",
                "http://www.cipherdyne.org\n";
        }
        system "$cmds{'make'} clean" if -e 'Makefile';
        system "$cmds{'perl'} Makefile.PL PREFIX=$config{'FWKNOP_MOD_DIR'} " .
            "LIB=$config{'FWKNOP_MOD_DIR'}";
        system $cmds{'make'};
#        system "$cmds{'make'} test";
        system "$cmds{'make'} install";
        chdir $src_dir or die "[*] Could not chdir $src_dir: $!";
    }

    unless ($client_install) {

        ### install man pages
        &install_manpage('knopmd.8');
        &install_manpage('knopwatchd.8');
        &install_manpage('fwknop.8');
        &install_manpage('fwknopd.8');

        if (-e "$config{'FWKNOP_CONF_DIR'}/fwknop.conf") {
            $preserve_rv = &query_preserve_config();
        }

        print "[+] Compiling knopmd and knopwatchd daemons:\n";

        ### remove any previously compiled knopmd
        unlink 'knopmd' if -e 'knopmd';

        ### remove any previously compiled knopwatchd
        unlink 'knopwatchd' if -e 'knopwatchd';

        ### compile the C fwknop daemons
        system $cmds{'make'};

        unless (-e 'knopmd' and -e 'knopwatchd') {
            die "[*] Compilation failed.";
        }

        ### install fwknop server-side daemons/programs
        for my $daemon qw(fwknopd knopmd knopwatchd knoptm fwknop_serv) {
            if ($daemon eq 'fwknopd' or $daemon eq 'knoptm') {
                unless (((system "$cmds{'perl'} -c $daemon")>>8) == 0) {
                    die "[*] $daemon does not compile with \"perl -c\".  ",
                        "Download the latest sources ",
                        "from:\n\nhttp://www.cipherdyne.org/\n";
                }
            }
            print "[+] Copying $daemon -> $USRSBIN_DIR\n";
            copy $daemon, $USRSBIN_DIR or
                die "[*] Could not cp $daemon to $USRSBIN_DIR: $!";
            chmod 0500, "$USRSBIN_DIR/$daemon" or
                die "[*] Could not chmod 500 $USRSBIN_DIR/$daemon: $!";
        }
    }

    print "[+] Copying fwknop -> $USRBIN_DIR\n";
    copy 'fwknop', $USRBIN_DIR or
        die "[*] Could not cp fwknop to $USRBIN_DIR: $!";

    if ($client_install) {
        open F, "< $USRBIN_DIR/fwknop" or die "[*] Could not open ",
            "$USRBIN_DIR/fwknop: $!";
        my @lines = <F>;
        close F;
        open P, "> $USRBIN_DIR/fwknop.tmp" or die "[*] Could not open ",
            "$USRBIN_DIR/fwknop.tmp: $!";
        for my $line (@lines) {
            ### change the lib dir to new homedir path
            if ($line =~ m|^\s*use\s+lib\s+\'/usr/lib/fwknop\';|) {
                print P "use lib '", $config{'FWKNOP_MOD_DIR'}, "';\n";
            } else {
                print P $line;
            }
        }
        close P;
        move "$USRBIN_DIR/fwknop.tmp", "$USRBIN_DIR/fwknop" or die "[*] Could ",
            "not move $USRBIN_DIR/fwknop.tmp -> $USRBIN_DIR/fwknop: $!";
        chmod 0700, "$USRBIN_DIR/fwknop" or
            die "[*] Could not chmod 755 $USRBIN_DIR/fwknop: $!";
    } else {
        chmod 0755, "$USRBIN_DIR/fwknop" or
            die "[*] Could not chmod 755 $USRBIN_DIR/fwknop: $!";
    }

    unless (((system "$cmds{'perl'} -c $USRBIN_DIR/fwknop")>>8) == 0) {
        die "[*] $USRBIN_DIR/fwknop does not compile with \"perl -c\".  ",
            "Download the latest sources ",
            "from:\n\nhttp://www.cipherdyne.org/\n";
    }


    if ($client_install) {
        print
"\n[+] fwknop has been installed at $USRBIN_DIR/fwknop.  Since this is a\n",
"    client-only install, the man pages could not be installed.  For more\n",
"    information about how to use fwknop, execute \"$USRBIN_DIR/fwknop -h\" or\n",
"    refer to:\n\n",
"        http://www.cipherdyne.org/fwknop/docs/manpages/index.html\n\n";

    } else {

        ### install config and access files
        for my $file qw(fwknop.conf access.conf pf.os) {
            if (-e "$config{'FWKNOP_CONF_DIR'}/$file") {
                &archive("$config{'FWKNOP_CONF_DIR'}/$file");
                if ($preserve_rv) {
                    if ($file eq 'access.conf') {
                        ### access.conf can have missing fields (i.e.
                        ### REQUIRE_OS_REGEX and REQUIRE_USERNAME),
                        ### and also it can have multiple sequences
                        ### defined.  Hence we just use the old one.
                        print "[+] Using original access.conf\n";
                    } elsif ($file ne 'pf.os') {
                        &preserve_config($file);
                    }
                } else {
                    print "[+] Copying $file -> $config{'FWKNOP_CONF_DIR'}\n";
                    copy $file, $config{'FWKNOP_CONF_DIR'} or
                        die "[*] Could not cp $file to $config{'FWKNOP_CONF_DIR'}";
                }
            } else {
                print "[+] Copying $file -> $config{'FWKNOP_CONF_DIR'}\n";
                copy $file, $config{'FWKNOP_CONF_DIR'} or
                    die "[*] Could not cp $file to $config{'FWKNOP_CONF_DIR'}";
            }

            if ($force_path_update or not $preserve_rv) {
                &update_command_paths("$config{'FWKNOP_CONF_DIR'}/$file")
                    if ($file eq 'fwknop.conf');
            }

            if ($file eq 'fwknop.conf') {
                &set_hostname("$config{'FWKNOP_CONF_DIR'}/$file");
            }
            chmod 0600, "$config{'FWKNOP_CONF_DIR'}/$file" or die
                "[*] Could not chmod(600, $config{'FWKNOP_CONF_DIR'}/$file: $!";
            chown 0, 0, "$config{'FWKNOP_CONF_DIR'}/$file" or die
                "[*] Could not chown 0,0, $config{'FWKNOP_CONF_DIR'}/$file: $!";
        }

        ### get data acquisition method (e.g. syslogd, sysylog-ng, ulogd
        ### or pcap)
        $data_method = &query_data_method();

        if ($data_method =~ /syslog/) {

            ### create the named pipe
            unless (-e $config{'KNOPMD_FIFO'} and -p $config{'KNOPMD_FIFO'}) {
                unlink $config{'KNOPMD_FIFO'} if -e $config{'KNOPMD_FIFO'};
                print "[+] Creating named pipe $config{'KNOPMD_FIFO'}\n";
                my $created_pipe = 1;
                unless (((system "$cmds{'mknod'} -m 600 $config{'KNOPMD_FIFO'} p")>>8)
                        == 0) {
                    $created_pipe = 0;
                }
                unless (-e $config{'KNOPMD_FIFO'} and -p $config{'KNOPMD_FIFO'}) {
                    $created_pipe = 0;
                }
                unless ($created_pipe) {
                    die
"[*] Could not create the named pipe \"$config{'KNOPMD_FIFO'}\"!\n",
"[*] fwknop requires this file to exist!  Aborting install.\n";
                }
            }

            unless (-e "$config{'FW_DATA_FILE'}") {
                print "[+] Creating $config{'FW_DATA_FILE'} file\n";
                open F, "> $config{'FW_DATA_FILE'}" or die "[*] Could not open ",
                    "$config{'FW_DATA_FILE'}: $!";
                close F;
                &perms_ownership("$config{'FW_DATA_FILE'}", 0600);
            }

            ### we are acquiring data via syslog
            &put_string('AUTH_MODE', 'KNOCK',
                "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");

            if ($os_type == $OS_BSD or $os_type == $OS_DARWIN) {
                ### update to use the ipfw firewall on *BSD systems
                &put_string('FIREWALL_TYPE', 'ipfw',
                    "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");
            }

            &put_string('SYSLOG_DAEMON', $data_method,
                "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");

            my $restarted_syslog = 0;
            if ($data_method eq 'syslogd') {
                if (-e $syslog_conf) {
                    &append_fifo_syslog($syslog_conf);
                    if (((system "$cmds{'killall'} -HUP syslogd " .
                            "2> /dev/null")>>8) == 0) {
                        print "[+] HUP signal sent to syslogd.\n";
                        $restarted_syslog = 1;
                    }
                }
            } elsif ($data_method eq 'syslog-ng') {
                if (-e $syslog_conf) {
                    &append_fifo_syslog_ng($syslog_conf);
                    if (((system "$cmds{'killall'} -HUP syslog-ng " .
                            "2> /dev/null")>>8) == 0) {
                        print "[+] HUP signal sent to syslog-ng.\n";
                        $restarted_syslog = 1;
                    }
                }
            }

            unless ($restarted_syslog) {
                print "[-] Could not restart any syslog daemons.\n";
            }
        } elsif ($data_method =~ /pcap/i or $data_method =~ /ulog/i) {

            if ($os_type == $OS_BSD or $os_type == $OS_DARWIN) {
                ### update to use the ipfw firewall on *BSD systems
                &put_string('FIREWALL_TYPE', 'ipfw',
                    "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");
            }

            ### we are using a pcap method
            if ($data_method eq 'ulogd' or $data_method eq 'file_pcap') {
                print
"[+] By default, fwknop uses the file /var/log/sniff.pcap in order to\n",
"    acquire packet data logged via a sniffer (or ulogd) to a pcap file,\n",
"    but this path may be changed by altering the PCAP_PKT_FILE keyword\n",
"    in $config{'FWKNOP_CONF_DIR'}/fwknop.conf.\n\n";

                if ($data_method eq 'file_pcap') {
                    &put_string('AUTH_MODE', 'FILE_PCAP',
                        "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");
                } else {
                    &put_string('AUTH_MODE', 'ULOG_PCAP',
                        "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");
                }
            } else {
                unless ($sniff_interface) {
                    $sniff_interface = &get_pcap_intf();
                }
                if ($sniff_interface) {
                    &put_string('PCAP_INTF', $sniff_interface,
                        "$config{'FWKNOP_CONF_DIR'}/fwknop.conf");
                } else {
print "[-] Could not get sniffing interface, edit the PCAP_INTF var in\n",
    "    config{'FWKNOP_CONF_DIR'}/fwknop.conf\n";
                }
            }
        } else {
            ### it is a client-only install, so don't reconfigure syslog
            ### or anything.
        }

        unless ($preserve_rv) {
            my $email_str = &query_email();
            if ($email_str) {
                for my $file qw(fwknop.conf) {
                    &put_string('EMAIL_ADDRESSES', $email_str,
                        "$config{'FWKNOP_CONF_DIR'}/$file");
                }
            }
        }


        if ($client_install) {
            print "\n[+] fwknop has been installed!\n\n";
        } else {

            &get_init_dir();
            if (-d $init_dir) {
                &enable_fwknop_at_boot($distro);
            }

            print "\n[+] fwknop has been installed!";

            if ($os_type == $OS_LINUX) {
                print "  To start in server mode, run\n\n",
                    "    \"$init_dir/$init_name start\"\n\n";
            } else {
                print "\n\n";
            }
            print
"    You may want to consider running the fwknop test suite in the test/\n",
"    directory to ensure that fwknop will function correctly on your system.\n\n",

"    Note: You will need to edit $config{'FWKNOP_CONF_DIR'}/access.conf for fwknop to\n",
"    function properly in server mode.  More information can be found in\n",
"    the fwknopd(8) manpage.\n\n";
            if ($os_type == $OS_BSD or $os_type == $OS_DARWIN) {
                print
"    You may need to update your /etc/syslog.conf file to log local info\n",
"    messages to a file in the /var/log/ directory in order to see syslog\n",
"    messages from the fwknop daemons.\n\n";
            }
        }
    }
    return;
}

sub uninstall() {

    print "[+] Uninstalling fwknop...\n";

    ### stop any running fwknop daemons.
    &stop_fwknop();

    ### get the init directory
    &get_init_dir();

    for my $daemon qw(fwknopd knopmd knopwatchd knoptm fwknop_serv) {
        unlink "$USRSBIN_DIR/$daemon" if -e "$USRSBIN_DIR/$daemon";
    }
    unlink "$USRBIN_DIR/fwknop" if -e "$USRBIN_DIR/fwknop";
    unlink "$init_dir/$init_name" if -e "$init_dir/$init_name";
    rmtree $config{'FWKNOP_CONF_DIR'}, 1, 1 if -d $config{'FWKNOP_CONF_DIR'};
    rmtree $config{'FWKNOP_LIB_DIR'}, 1, 1 if -d $config{'FWKNOP_LIB_DIR'};
    rmtree $config{'FWKNOP_MOD_DIR'}, 1, 1 if -d $config{'FWKNOP_MOD_DIR'};

    return;
}

sub get_init_dir() {
    return if $client_install;

    if ($os_type == $OS_DARWIN) {

        ### Mac OS X init directory for user programs
        $init_dir = '/Library/StartupItems';
        die "[*] The $init_dir directory does not exist."
            unless -d $init_dir;
        return;
    }

    ### accommodates Linux and BSD systems
    unless (-d $init_dir) {
        if (-d '/etc/rc.d/init.d') {
            $init_dir = '/etc/rc.d/init.d';
        } elsif (-d '/etc/rc.d') {
            $init_dir = '/etc/rc.d';
        } elsif (-d '/etc/init.d') {
            $init_dir = '/etc/init.d';
        } else {
            die "[*] Cannot find the init script directory, use ",